Hauptmenü öffnen

Datei:ESt D Splitting 2018 zvE bis 120000.svg

Originaldatei(SVG-Datei, Basisgröße: 1.000 × 600 Pixel, Dateigröße: 190 KB)

Commons-logo.svg Diese Datei und die Informationen unter dem roten Trennstrich werden aus dem zentralen Medienarchiv Wikimedia Commons eingebunden. Zur Beschreibungsseite auf Commons Zur Beschreibungsseite auf Commons

Beschreibung

Beschreibung
English: Tax rate as percentage of taxable income and marginal tax rate in Germany for singles and married couples in tax year 2018
Deutsch: Durchschnittsteuersatz in Prozent des zu versteuernden Einkommens sowie Grenzsteuersatz von Alleinstehenden und Verheirateten bei der Einkommensteuer in Deutschland für den Veranlagungszeitraum 2018
Datum
Quelle Eigenes Werk
Urheber Udo Brechtel
#-------------------------------------------------------------
# Script for gnuplot 5.0, Lizenz: CC-BY-SA-4.0 by Udo Brechtel
#-------------------------------------------------------------
reset
#-------------------------------------------------------------
# Variablendeklaration:
#-------------------------------------------------------------
#Canvas:
xsize = 1000
ysize = 600
xleftmargin = 10
ytopmargin  = 5
 
Jahr = 2018
 
conv = 1000
 
#Wertebereich:
zvEmin = 0; zvEmax = 120000; zvEstep = 5000
 
#x-/y-Achse (konvertiert):
xmin = zvEmin/conv; xmax = zvEmax/conv; dx = zvEstep/conv
ymin = 0;           ymax = 50;          dy = 5
 
#Legende Position:
xkey = 2; ykey = 48
 
#Diagrammtitel:
lblTITEL  = "Einkommensteuer Deutschland";
lblTITEL2 = "Grund- und Splittingtarif ".Jahr;
lblYACHSE = "Durchschnitt-/Grenzsteuersatz"
lblXACHSE = "Jährlich zu versteuerndes Einkommen (Euro)"
 
lblZUSATZINFO = "EStG § 32a gültig ab 1. Januar 2018"
 
fontterm        = "Arial, 10"
fonttitle       = "Arial Bold, 14"
fonttitle2       = "Arial Bold, 16"
fontxytics      = "Arial, 12"
fontxylabels    = "Arial Bold, 12"
fontkeylabels   = "Arial Bold, 11"
fontlabels      = "Arial, 6"
 
#Linienstyles s
set style line 8000 lt 1 lw 0.6 lc rgb "black"
set style line 8001 lt 1 lw 0.4 lc rgb "gray"
set style line 8002 lt 1 lw 0.1 lc rgb "gray"

#----------------------------------------------------------------------------
# Settings
#----------------------------------------------------------------------------
#set encoding iso_8859_1 
set encoding utf8

set noborder #3 ls 8001
set zeroaxis ls 8000
 
set sample 1201
 
set terminal svg size xsize,ysize font fontterm dashed background rgb "white"
set lmargin xleftmargin
set tmargin ytopmargin
 
#Diagrammtitel
set title lblTITEL offset 10,1 font fonttitle
set label at 54,52.5 left lblTITEL2 font fonttitle2

#Legende (key)
set label at -7,55 left "Grenzsteuersatz (gestrichelte Linie)\n∅-Steuersatz (durchgezogene Linie)" font fontkeylabels
 
set key at xkey,ykey left Left spacing 1.5 width 1 height 1 box ls 8001
set key opaque reverse   vertical maxrows 8
set key font fontkeylabels
 
#y-Achse
set yrange [ymin:ymax]
set format y "%.0f %%"
set ytics out nomirror ymin,dy font fontxytics
set ytics add ("0" 0)
set mytics dy
#set ylabel lblYACHSE offset -0.8,0 font fontxylabels
 
#x-Achse
set xrange [xmin:xmax]
set format x "%g 000" #Tausendertrennung
set xtics out nomirror rotate xmin,dx font fontxytics
set mxtics dx
set xtics add ("0" 0)
set xlabel lblXACHSE offset (2*dx),-0.5 font fontxylabels
 
#Labels Info
set label at -7,-10 left lblZUSATZINFO font fontlabels
 
#Gitternetz
set grid xtics mxtics ytics mytics ls 8001, ls 8002
 
#-------------------------------------------------------------
# Einkommensteuertarif 2018:
#-------------------------------------------------------------
# Eckwerte zvE (obere Grenze):
 e(n) =   9000*(n==0) \
      +  13996*(n==1) \
      +  54949*(n==2) \
      + 260532*(n==3) 
 
# Welche Zone?
 n(zve) = 0*           (zve<=e(0)) \
        + 1*(zve>e(0))*(zve<=e(1)) \
        + 2*(zve>e(1))*(zve<=e(2)) \
        + 3*(zve>e(2))*(zve<=e(3)) \
        + 4*(zve>e(3))
 
# Eckwert zur Differenzbildung
 ea(n) =   e(0)*(n==1) \
       +   e(1)*(n==2)
 
# Linearer Progressionsfaktor:
 a(n) = 997.8 e-8*(n==1) \
      + 220.13e-8*(n==2)
 
# Anfänglicher Grenzsteuersatz:
 b(n) = 0.1400*(n==1) \
      + 0.2397*(n==2) \
      + 0.42  *(n==3) \
      + 0.45  *(n==4) 
 
# y-Achsenabschnitt bzw. StB der unteren Zonen:
 c(n) =    948.49*(n==1) \
      +  -8621.75*(n==2) \
      + -16437.7 *(n==3) 
#-------------------------------------------------------------
#Funktionen:
#-------------------------------------------------------------
 
# Abzuziehender Eckwert :
 ean(zve) = ea(n(zve))
 
 zve(x)  = x*conv
 dzve(x) = zve(x) - ean(zve(x))
 
# Massgebender linearer Progressionsfaktor
 an(zve) = a(n(zve))
 
# Massgebender Grenzsteuersatz
 bn(zve) = b(n(zve))
 
# Massgebender y-Achsenabschnitt bzw. StB der unteren Zonen:
 cn(zve) = c(n(zve)-1)
 
 
#Steuerbetrag
# -Grundtarif     (v==0)
# -Splittingtarif (v==1)
 Stb0(x) = ( an(zve(x))*dzve(x)**2 + bn(zve(x))*dzve(x) + cn(zve(x)) ) /conv
 Stb1(x) = 2*Stb0(x/2)
 Stb(x,v) = Stb0(x)*(v==0) + Stb1(x)*(v==1)
 
#Grenzsteuersatz
 sg0(x) = ( 2*an(zve(x))  *dzve(x)   + bn(zve(x))   ) * 100
 sg1(x) = ( 2*an(zve(x/2))*dzve(x/2) + bn(zve(x/2)) ) * 100
 sg(x,v) = sg0(x)*(v==0) + sg1(x)*(v==1)
 
#Durchschnittsteuersatz alle Zonen
 s(x,v) = Stb(x,v) * 100 / x
 
#-----------------------------------------------------------------
 
#Linienstyles sg
set style line 13000 dt 2 lw 1.1 lc rgb "blue"
set style line 13001 dt 2 lw 1.1 lc rgb "red"
#Linienstyles s
set style line 13010 lt 1 lw 1.2 lc rgb "blue"
set style line 13011 lt 1 lw 1.2 lc rgb "red"
 
#-----------------------------------------------------------------
#Ausgabedatei
fn = "ESt_D_Splitting_".Jahr."_zvE_bis_".zvEmax.".svg"
 
set output fn
 
plot sg(x,0) ls 13000 notitle, \
     sg(x,1) ls 13001 notitle, \
     s(x,0)  ls 13010 t "Grundtarif", \
     s(x,1)  ls 13011 t "Splittingtarif"
     
unset output

#EOF

Lizenz

Ich, der Urheber dieses Werkes, veröffentliche es unter der folgenden Lizenz:
w:de:Creative Commons

Namensnennung Weitergabe unter gleichen Bedingungen

Diese Datei ist lizenziert unter der Creative-Commons-Lizenz „Namensnennung – Weitergabe unter gleichen Bedingungen 4.0 international“.
Dieses Werk darf von dir
  • verbreitet werden – vervielfältigt, verbreitet und öffentlich zugänglich gemacht werden
  • neu zusammengestellt werden – abgewandelt und bearbeitet werden
Zu den folgenden Bedingungen:
  • Namensnennung – Du musst angemessene Urheber- und Rechteangaben machen, einen Link zur Lizenz beifügen und angeben, ob Änderungen vorgenommen wurden. Diese Angaben dürfen in jeder angemessenen Art und Weise gemacht werden, allerdings nicht so, dass der Eindruck entsteht, der Lizenzgeber unterstütze gerade dich oder deine Nutzung besonders.
  • Weitergabe unter gleichen Bedingungen – Wenn du das lizenzierte Werk bzw. den lizenzierten Inhalt bearbeitest, abwandelst oder in anderer Weise erkennbar als Grundlage für eigenes Schaffen verwendest, darfst du die daraufhin neu entstandenen Werke bzw. Inhalte nur unter Verwendung von Lizenzbedingungen weitergeben, die mit denen dieses Lizenzvertrages identisch, vergleichbar oder kompatibel sind.

Dateiversionen

Klicke auf einen Zeitpunkt, um diese Version zu laden.

Version vomVorschaubildMaßeBenutzerKommentar
aktuell16:47, 25. Jul. 2018Vorschaubild der Version vom 25. Juli 2018, 16:47 Uhr1.000 × 600 (190 KB)Udo.Brechtel{{Information |description ={{en|1=Tax rate as percentage of taxable income and marginal tax rate in Germany for singles and married couples in tax year 2018}} {{de|1=Durchschnittsteuersatz in Prozent des zu versteuernden Einkommens sowie Grenzsteuersatz von Alleinstehenden und Verheirateten bei der Einkommensteuer in Deutschland für den Veranlagungszeitraum 2018}} |date =20...

Metadaten