#!/usr/bin/gnuplot
# gnuplot 


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key
set style data lines
set style fill transparent solid 0.4
set grid


# Bereiche/Format/etc X-Achse 
set xdata time
set xlabel 'Jahr'
set xrange ['30.06.1812':'30.06.1942']
set xtics '01.01.1000', 60 * 60 * 24 * 365.25 * 25
                      #  xtics in Sekunden 
                      # der Beginn der X-Einteilung kann außerhalb xrange
                      # liegen
set mxtics 5          # Unterteilung der Skalierung
set xtics nomirror    # Nur unten Skalieren
set format x '%Y'     # Beschriftungsformat JJJJ


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl'
set yrange [0:]
set ytics 2500
set mytics 5
set ytics nomirror
set decimalsign locale "de_DE.utf8"
set decimal     locale "de_DE.utf8"
set format y  "%'.0f" # Ausgabeformat


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,14"  dashed
# set termoption dashed # sollte bei Probl. m. gestrichelten L. gesetzt werden
# keine "set output '<Dateiname>'" Angabe


# Erzeugen der Ausgabe 
plot \
  '-' using 1:($2) with linespoints linecolor 'dark-blue'   linetype 1 linewidth 1.5 pointtype 7 pointsize 0.25,\
  '-' using 1:($2) with linespoints linecolor 'dark-red'    linetype 1 linewidth 1.5 pointtype 7 pointsize 0.25,\
  '-' using 1:($2) with linespoints linecolor 'dark-green'  linetype 1 linewidth 1.5 pointtype 7 pointsize 0.25,\
  '-' using 1:($2) with linespoints linecolor 'dark-yellow' linetype 1 linewidth 1.5 pointtype 7 pointsize 0.25,\
  '-' using 1:($2) with linespoints linecolor 'magenta'     linetype 1 linewidth 1.5 pointtype 7 pointsize 0.25


# Quelle:
# https://de.wikipedia.org/wiki/Ingelheim_am_Rhein#Einwohnerentwicklung
# (dort die Tabelle "Vor der Stadtwerdung")

# Gesamt 'dark-blue'
30.06.1815;3967
30.06.1834;5737
30.06.1861;6442
30.06.1900;7675
30.06.1905;8489
30.06.1910;8213
30.06.1933;10456
30.06.1939;11035
EOF
#
# Nieder-Ingelheim 'dark-red'
30.06.1815;1360
30.06.1834;2130
30.06.1861;2352 
30.06.1900;3435 
30.06.1905;3435 
30.06.1910;3852 
30.06.1933;5157 
30.06.1939;5526 
EOF
#
# Ober-Ingelheim 'dark-green'
30.06.1815;1738 
30.06.1834;2371 
30.06.1861;2673 
30.06.1900;3402 
30.06.1905;3402 
30.06.1910;3479 
30.06.1933;4116 
30.06.1939;4309 
EOF
#
# Frei-Weinheim 'dark-yellow'
30.06.1815;192 
30.06.1834;439 
30.06.1861;606 
30.06.1900;838 
30.06.1905;838 
30.06.1910;882 
30.06.1933;1183 
30.06.1939;1200 
EOF
#
# Großwinternheim 'magenta'
30.06.1815;677 
30.06.1834;797 
30.06.1861;811 
30.06.1905;814 
EOF