Datei:Bohr-sommerfeld Atommodell (Elektronenbahnen).svg

Beschreibung, Quelle Bearbeiten

Bild wurde mit folgendem Programm erstellt.

# *************************************************************************
# *
# * ellipsen.gplot
# *
# * Programm zum Zeichnen von Elektronenbahnen 
# * des bohr-sommerfeldschen Atommodells 
# * für ein Wasserstoffatom
# * Versionen: - 2006.11.01 http://de.wikipedia.org/wiki/Benutzer:Dibe
#                PNG-Plot
#              - 2008.12.31 http://de.wikipedia.org/wiki/Benutzer:Cepheiden
#                SVG-Plot, Farbanpassungen, Achsen in Angström
# * Ausgeführt mit gnuplot 4.3 
# *************************************************************************
# Naturkonstanten:
#   h:     Plancksches Wirkungsquantum
#   h_:    h-quer (plancksches Wirkungsquantum / (2 * PI))
#   e0:    Elementarladung (Ladung eines Elektrons)
#   me:    MasseBKL eines Elektrons
#   eps0:  Dielektrizitätskonstante
# Abgeleitete Werte:
#   mr:    Reduzierte Masse eines Elektrons im Wasserstoffatom
#   G:     Stärke des Coulomb-Potentials
# Hilfsvariable:
#   h_2, K
# Funktionen:
#   enrg(n) :    Energie zum Energieniveau mit der Hauptquantenzahl n
#   l_2(l):      Quadrat des Betrags des Drehimpulses 
#                zur Nebenquantenzahl l
#   nmexc(n,l):  Numerische Exzentrizität der Bahnellipse 
#                zur Hauptquantenzahl n und Nebenquantenzahl l
#   rad(t,n,l):  Radius der Elektronenbahn zum Winkel t 
#                bei Hauptquantenzahl n und Nebenquantenzahl l 
#
# (Alle Größen sind im MKS-System angegeben)
# **************************************************************************

reset

#Konstanten
h       = 6.62606896E-34
h_      = h/(2.0*pi)
e0      = 1.602176487E-19
me      = 9.10938215E-31
eps0    = 8.85418781762E-12

#Abgeleitete Werte
mr      = me*1.00055
h_2     = h_ * h_
G       = e0*e0/(4.0*pi*eps0)
K       = mr * G

#Funktionen
enrg(n)      = -mr * (e0**4) / (32.0 * (pi**2) * (eps0**2) * h_2 * (n**2))
l_2(l)       = (l+1.) * (l+1.) * h_2
nmexz(n,l)   = 1 + 2.0 * enrg(n) * l_2(l)/ mr / (G**2)
rad(phi,n,l) = l_2(l)/K/(1.0 + sqrt(nmexz(n,l))*cos(pi-phi))

#Plotten
set term svg size 600,400 fname 'DejaVu Sans' fsize 11 butt solid
set output "bohr-sommerfeld.svg" 

set key at 10.2,5.2 right

set style line 1 lt 2 lc rgb "#FF0000" lw 4
set style line 2 lt 2 lc rgb "#CCFF00" lw 4
set style line 3 lt 2 lc rgb "#00CC00" lw 4
set style line 4 lt 2 lc rgb "#66B3FF" lw 4
set style line 5 lt 2 lc rgb "#005CB8" lw 4
set style line 6 lt 2 lc rgb "#00376E" lw 4
set style line 7 lt 2 lc rgb "#000000" lw 2

set decimalsign ','
set encoding iso_8859_1  
set clip points
unset border
set dummy t
set polar
set angles radians
set samples 320, 320
set xzeroaxis ls 7
set yzeroaxis ls 7
set xtics axis nomirror norotate autofreq
set ytics axis nomirror norotate autofreq
set title "" font ""
set trange [0.0 : 2 * pi ] noreverse nowriteback
set format y "%.0f \305"
set format x "%.0f \305"

plot rad(t,1,0)*1e10 ls 1 title "n=1, l=0", \
     rad(t,2,0)*1e10 ls 2 title "n=2, l=0", \
     rad(t,2,1)*1e10 ls 3 title "n=2, l=1", \
     rad(t,3,0)*1e10 ls 4 title "n=3, l=0", \
     rad(t,3,1)*1e10 ls 5 title "n=3, l=1", \
     rad(t,3,2)*1e10 ls 6 title "n=3, l=2", \
     0.2*rad(t,1,0)*1e10 ls 7 notitle with filledcurves closed

Lizenz Bearbeiten

Diese Datei wurde unter der GNU-Lizenz für freie Dokumentation veröffentlicht. Es ist erlaubt, die Datei unter den Bedingungen der GNU-Lizenz für freie Dokumentation, Version 1.2 oder einer späteren Version, veröffentlicht von der Free Software Foundation, zu kopieren, zu verbreiten und/oder zu modifizieren. Es gibt keine unveränderlichen Abschnitte, keinen vorderen Umschlagtext und keinen hinteren Umschlagtext. GFDL GNU-Lizenz für freie Dokumentation //de.wikipedia.org/wiki/Wikipedia:GNU_Free_Documentation_License

Diese Datei wurde unter den Bedingungen der „Creative Commons Namensnennung-Weitergabe unter gleichen Bedingungen Unported“-Lizenz (abgekürzt „cc-by-sa“) in der Version 3.0 veröffentlicht. Lizenzvertrag: https://creativecommons.org/licenses/by-sa/3.0/legalcode Eine Zusammenfassung des Lizenzvertrags in allgemeinverständlicher Sprache, ohne juristische Wirkung, befindet sich hier. CC-BY-SA-3.0 Creative Commons Namensnennung-Weitergabe unter gleichen Bedingungen Unported 3.0 https://creativecommons.org/licenses/by-sa/3.0/legalcode

Diese ursprünglich nur unter der GNU Free Documentation License (GFDL, Version 1.3) lizenzierte Datei ist in Folge der Lizenzumstellung der Wikipedia auch unter den Bedingungen der Creative Commons Attribution-Share Alike 3.0 nutzbar. Dieser Umstand muss beim Übertragen dieser Datei auf Wikimedia Commons dokumentiert bleiben. The information that this file is available under CC-by-sa due to relicensing must remain documented after migration to Wikimedia Commons.

Lizenz: Bearbeiten

Diese Datei wurde unter der GNU-Lizenz für freie Dokumentation veröffentlicht. Es ist erlaubt, die Datei unter den Bedingungen der GNU-Lizenz für freie Dokumentation, Version 1.2 oder einer späteren Version, veröffentlicht von der Free Software Foundation, zu kopieren, zu verbreiten und/oder zu modifizieren. Es gibt keine unveränderlichen Abschnitte, keinen vorderen Umschlagtext und keinen hinteren Umschlagtext. GFDL GNU-Lizenz für freie Dokumentation //de.wikipedia.org/wiki/Wikipedia:GNU_Free_Documentation_License

Diese Datei wurde unter den Bedingungen der „Creative Commons Namensnennung-Weitergabe unter gleichen Bedingungen Unported“-Lizenz (abgekürzt „cc-by-sa“) in der Version 3.0 veröffentlicht. Lizenzvertrag: https://creativecommons.org/licenses/by-sa/3.0/legalcode Eine Zusammenfassung des Lizenzvertrags in allgemeinverständlicher Sprache, ohne juristische Wirkung, befindet sich hier. CC-BY-SA-3.0 Creative Commons Namensnennung-Weitergabe unter gleichen Bedingungen Unported 3.0 https://creativecommons.org/licenses/by-sa/3.0/legalcode

Diese ursprünglich nur unter der GNU Free Documentation License (GFDL, Version 1.3) lizenzierte Datei ist in Folge der Lizenzumstellung der Wikipedia auch unter den Bedingungen der Creative Commons Attribution-Share Alike 3.0 nutzbar. Dieser Umstand muss beim Übertragen dieser Datei auf Wikimedia Commons dokumentiert bleiben. The information that this file is available under CC-by-sa due to relicensing must remain documented after migration to Wikimedia Commons.